Kijken of een cel bepaald woord bevat

Waarschuwing - niet hoofdlettergevoelig...

Als je wilt kijken of een cel een bepaald woord bevat, doe je dat met geneste ALS-functie met ISGETAL en VIND.SPEC.

Voorbeeld met formules

=ALS( ISGETAL( VIND.SPEC( $C$1; D6)); "Ja"; "Nee")// cel E6, output: Ja

De buitenste functie is de ALS-functie, die een logische test uitvoert. De logische test is weer een geneste formule met ISGETAL en VIND.SPEC.

De VIND.SPEC-functie kijkt of de waarde uit het tweede argument, in het eerste argument zit. Als dat zo is, dan krijg je de positie (als getal) waarop dit het eerst voorkomt. Als deze functie echter niets vindt, dan krijg je #WAARDE!.

Om die reden moeten we de VIND.SPEC-functie nog nesten in een ALS en ISGETAL. Als de VIND.SPEC-functie iets vindt, en dus een getal geeft, dan wordt ISGETAL een WAAR. Als de VIND.SPEC-functie niets vindt en dus #WAARDE! geeft, dan wordt de ISGETAL-functie ONWAAR.

De ALS-functie maakt het vervolgens af:

=ALS( ISGETAL( VIND.SPEC( $C$1; D6)); "Ja"; "Nee")
=ALS( ISGETAL( VIND.SPEC( "Sr."; "Sr. xyz")); "Ja"; "Nee")
=ALS( ISGETAL( 1); "Ja"; "Nee")
=ALS( WAAR; "Ja"; "Nee")
="Ja"

Zoals je in het plaatje bovenaan kunt zien, is deze formule NIET hoofdlettergevoelig: VIND.SPEC is niet hoofdlettergevoelig. Zie meer voorbeelden hieronder.

Korte uitleg voor gebruikte functies

=ALS( 1<2; "Ja"; "Nee")// Geeft "Ja"
=ALS( 1>2; "Ja"; "Nee")// Geeft "Nee"
=ISGETAL( 123)// Geeft WAAR
=ISGETAL( "Abc 123")// Geeft ONWAAR
=VIND.SPEC( "b"; "abc abc")// Geeft 2
=VIND.SPEC( "B"; "abc abc")// Geeft 2, niet hoofdlettergevoelig
=VIND.SPEC( "b"; "aBc abc")// Geeft 2, niet hoofdlettergevoelig
=VIND.SPEC( "b"; "abc abc"; 3)// Geeft 6, ga pas kijken vanaf positie 3
=VIND.SPEC( "d"; "abc abc")// Geeft #WAARDE!