Eerste letter van tekst naar hoofdletter

aBc De → ABc De

Om zeker te zijn dat de eerste letter van een cel een hoofdletter is, kun je een formule met VERVANGEN, HOOFDLETTERS en LINKS gebruiken. Gebruik hiervoor niet de BEGINLETTERS-functie.

Er zijn ook nog alternatieve manieren om hetzelfde te bereiken, maar deze variant is de minst ingewikkelde.

Voorbeeld met formules

=VERVANGEN( C5; 1; 1; HOOFDLETTERS( LINKS( C5)))// cel D5, output: Kleine letters

De formule bestaat in feite uit de VERVANGEN-functie, waarbij het 4e input argument uit een geneste functie komt.

In de VERVANGEN-functie geef je aan dat je vanaf de eerste positie (input 2) 1 teken (input 3) wilt vervangen. Je wilt dit teken vervangen door de uitkomst van de geneste formule.

De geneste formule geeft de hoofdletter van het eerste teken.

=VERVANGEN( C5; 1; 1; HOOFDLETTERS( LINKS( C5)))
=VERVANGEN( "kleine letters"; 1; 1; HOOFDLETTERS( "k"))
=VERVANGEN( "kleine letters"; 1; 1; "K")
="Kleine letters"

Korte uitleg voor gebruikte functies VERVANGEN, HOOFDLETTERS en LINKS

Alleen VERVANGEN heeft wat meer uitleg nodig:

=VERVANGEN( "AbCdE 123 @#$"; 1; 3; "XXX")// Geeft "XXXdE 123 @#$"
=VERVANGEN( "AbCdE 123 @#$"; 7; 1; "XXX")// Geeft "AbCdE XXX23 @#$"
=VERVANGEN( "AbCdE 123 @#$"; 7; 3; "X")// Geeft "AbCdE X @#$"
=HOOFDLETTERS( "AbCdE 123 @#$")// Geeft "ABCDE 123 @#$"
=LINKS( "AbCdE 123 @#$")// Geeft "A"
=LINKS( "AbCdE 123 @#$"; 1)// Geeft "A"
=LINKS( "AbCdE 123 @#$"; 8)// Geeft "AbCdE 12"
=LINKS( "AbCdE 123 @#$"; 100)// Geeft "AbCdE 123 @#$"

Bij VERVANGEN hebben we 4 input argumenten nodig:

• input 1: In welke cel of waarde wil je gaan vervangen?
• input 2: Vanaf welke positie willen we vervangen?
• input 3: Hoeveel tekens willen we vervangen?
• input 4: Waarmee wil je die tekens vervangen?

In het tweede voorbeeld willen we vanaf de 7e positie 1 teken vervangen door "XXX".

In het derde voorbeeld willen vanaf de 7e positie 3 tekens (in dit geval "123") vervangen door "X".

In beide gevallen zie je dat de lengtes van wat je wilt vervangen en waardoor je wilt vervangen, niet gelijk hoeven te zijn.

HOOFDLETTERS vervangt alle kleine letters door hoofdletters. Alle hoofdletters, symbolen en spaties blijven ongemoeid.

LINKS geeft het gewenste aantal tekens, vanaf links. Als het aantal tekens (input argument 2) niet gedefinieerd is, dan gaat de functie uit van 1 teken. Als je "te veel" tekens vraagt, dan krijg je de gehele celwaarde.

Alternatieve formule

Je kunt ook een formule maken met HOOFDLETTERS, LINKS, DEEL en LENGTE:

=HOOFDLETTERS( LINKS( C5; 1))& DEEL( C5; 2; LENGTE( C5))// cel D5, output: Kleine letters

De formule bestaat uit 2 delen, verbonden met &. Het eerste deel maakt van de eerste letter een hoofdletter. Het tweede deel pakt de rest van de tekens, vanaf de 2e positie. Door de & plak je ze dan weer aan elkaar.

=HOOFDLETTERS( LINKS( C5; 1))& DEEL( C5; 2; LENGTE( C5))
=HOOFDLETTERS( "k")& DEEL( "kleine letters"; 2; 14)
="K"& "leine letters"
="Kleine letters"

In de formule staat LENGTE(C5), terwijl we ook LENGTE(C5)-1 hadden kunnen gebruiken. We vragen eigenlijk om een teken te veel. De uitkomst van de LENGTE-functie is een input voor de DEEL-functie.

Als je om "te veel" tekens vraagt in de DEEL-functie dan krijg je geen fout, maar dan stopt DEEL keurig aan het einde.

Uitleg voor gebruikte functies DEEL en LENGTE

Alle gebruikte functies zijn eenvoudig uit te leggen met minimale voorbeelden:

=DEEL( "AbCdE 123"; 3; 2)// Geeft "Cd"
=DEEL( "AbCdE 123"; 3; 10)// Geeft "CdE 123"
=LENGTE( "AbCdE 123")// Geeft 9

DEEL pakt vanaf de 3e positie (input 2) het aantal tekens uit input 3. Als je om "te veel" tekens vraagt, zoals in het tweede voorbeeld, dan stopt DEEL keurig aan het eind.

Veelgestelde vragen

Hoe verander ik de eerste letter van ieder woord (dus niet alleen van zin) in een hoofdletter?

Om ieder woord in een cel in een hoofdletter te veranderen, gebruik je de BEGINLETTERS-functie:

=BEGINLETTERS( "Dit is een zin")// geeft "Dit Is Een Zin"